Variable: gud-menu-map

gud-menu-map is a variable defined in gud.el.gz.

Value

<Continue to selection> <and> <gud-tool-bar-item-visible-no-fringe>  nil
<Continue-Run> <and> <gdb-show-run-p>                                nil
<Remove Breakpoint> <gud-tool-bar-item-visible-no-fringe>            nil
<Set Breakpoint> <gud-tool-bar-item-visible-no-fringe>               nil
<Show GUD tooltips> <and> <display-graphic-p>                        nil
<Stop> <or> <and> <gdb-show-stop-p>                                  nil
<displays> <keymap> <disassembly>                                    gdb-display-disassembly-buffer
<displays> <keymap> <frames>                                         gdb-display-stack-buffer
<displays> <keymap> <gdb>                                            gdb-display-gdb-buffer
<displays> <keymap> <inferior>                                       gdb-display-io-buffer(var)/gdb-display-io-buffer(fun)
<displays> <keymap> <load-layout>                                    gdb-load-window-configuration
<displays> <keymap> <locals>                                         gdb-display-locals-buffer
<displays> <keymap> <memory>                                         gdb-display-memory-buffer
<displays> <keymap> <registers>                                      gdb-display-registers-buffer
<displays> <keymap> <restore-layout-after-quit> <:toggle>            gdb-restore-window-configuration-after-quit
<displays> <keymap> <save-layout>                                    gdb-save-window-configuration
<displays> <keymap> <threads>                                        gdb-display-threads-buffer
<frames> <keymap> <disassembly>                                      gdb-frame-disassembly-buffer
<frames> <keymap> <frames>                                           gdb-frame-stack-buffer
<frames> <keymap> <gdb>                                              gdb-frame-gdb-buffer
<frames> <keymap> <inferior>                                         gdb-frame-io-buffer
<frames> <keymap> <locals>                                           gdb-frame-locals-buffer
<frames> <keymap> <memory>                                           gdb-frame-memory-buffer
<frames> <keymap> <registers>                                        gdb-frame-registers-buffer
<frames> <keymap> <threads>                                          gdb-frame-threads-buffer
<mi> <keymap> <all-threads> <:radio>                                 gdb-gud-control-all-threads
<mi> <keymap> <gdb-many-windows> <:toggle>                           gdb-many-windows(var)/gdb-many-windows(fun)

Documentation

Menu for gud-mode.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/gud.el.gz
(easy-menu-define gud-menu-map gud-menu-mode-map
  "Menu for `gud-mode'."
  '("Gud"
    ["Continue" gud-cont
     :enable (not gud-running)
     :visible (not (eq gud-minor-mode 'gdbmi))]
    ["Next Line" gud-next
     :enable (not gud-running)]
    ["Step Line" gud-step
     :enable (not gud-running)]
    ["Next Instruction" gud-nexti
     :enable (not gud-running)
     :visible (memq gud-minor-mode '(gdbmi gdb lldb dbx))]
    ["Step Instruction" gud-stepi
     :enable (not gud-running)
     :visible (memq gud-minor-mode '(gdbmi gdb lldb dbx))]
    ["Finish Function" gud-finish
     :enable (not gud-running)
     :visible (memq gud-minor-mode '(gdbmi gdb lldb guiler xdb jdb pdb))]
    ["Watch Expression" gud-watch
     :enable (not gud-running)
     :visible (eq gud-minor-mode 'gdbmi)]
    ["Print Expression" gud-print
     :enable (not gud-running)]
    ["Dump object-Dereference" gud-pstar
     :label (if (eq gud-minor-mode 'jdb)
                "Dump object"
              "Print Dereference")
     :enable (not gud-running)
     :visible (memq gud-minor-mode '(gdbmi gdb lldb jdb))]
    ["Print S-expression" gud-pp
     :enable (and (not gud-running)
		  (bound-and-true-p gdb-active-process))
     :visible (and (string-equal
		    (buffer-local-value
		     'gud-target-name gud-comint-buffer)
		    "emacs")
		   (eq gud-minor-mode 'gdbmi))]
    ["Down Stack" gud-down
     :enable (not gud-running)
     :visible (memq gud-minor-mode '(gdbmi gdb lldb guiler dbx xdb jdb pdb))]
    ["Up Stack" gud-up
     :enable (not gud-running)
     :visible (memq gud-minor-mode
		    '(gdbmi gdb lldb guiler dbx xdb jdb pdb))]
    ["Set Breakpoint" gud-break
     :enable (or (not gud-running) gud-async-running)
     :visible (gud-tool-bar-item-visible-no-fringe)]
    ["Temporary Breakpoint" gud-tbreak
     :enable (or (not gud-running) gud-async-running)
     :visible (memq gud-minor-mode '(gdbmi gdb lldb sdb xdb))]
    ["Remove Breakpoint" gud-remove
     :enable (or (not gud-running) gud-async-running)
     :visible (gud-tool-bar-item-visible-no-fringe)]
    ["Continue to selection" gud-until
     :enable (not gud-running)
     :visible (and (memq gud-minor-mode '(gdbmi gdb lldb perldb))
		   (gud-tool-bar-item-visible-no-fringe))]
    ["Stop" gud-stop-subjob
     :visible (or (not (memq gud-minor-mode '(gdbmi pdb)))
		  (and (eq gud-minor-mode 'gdbmi)
                       (gdb-show-stop-p)))]
    ["Continue-Run" gud-go
     :label (if (bound-and-true-p gdb-active-process)
                "Continue" "Run")
     :visible (and (eq gud-minor-mode 'gdbmi)
                   (gdb-show-run-p))]
    ["Run" gud-run
     :enable (or (not gud-running) gud-async-running)
     :visible (or (memq gud-minor-mode '(gdb lldb dbx jdb))
		  (and (eq gud-minor-mode 'gdbmi)
		       (or (not (gdb-show-run-p))
			   (bound-and-true-p
			    gdb-active-process))))]
    ["Refresh" gud-refresh]
    ["Show GUD tooltips" gud-tooltip-mode
     :enable (and (not emacs-basic-display)
		  (display-graphic-p)
		  (fboundp 'x-show-tip))
     :visible (memq gud-minor-mode
		    '(gdbmi lldb guiler dbx sdb xdb pdb))
     :button (:toggle . gud-tooltip-mode)]
    ["Info (debugger)" gud-goto-info]))