Variable: ispell-menu-map

ispell-menu-map is a variable defined in ispell.el.gz.

Value

<ispell-continue> <and> <equal> <current-buffer>  nil

Documentation

Key map for ispell menu.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/ispell.el.gz
;;;###autoload
(defconst ispell-menu-map
  ;; Use `defconst' so as to redo the menu when loading ispell, like the
  ;; previous code did.

  ;; Define commands in menu in opposite order you want them to appear.
  (let ((map (make-sparse-keymap "Spell")))
    (define-key map [ispell-change-dictionary]
      '(menu-item "Change Dictionary..." ispell-change-dictionary
                  :help "Supply explicit dictionary file name"))
    (define-key map [ispell-kill-ispell]
      `(menu-item "Kill Process"
                  ,(lambda () (interactive) (ispell-kill-ispell nil 'clear))
		  :enable (and (boundp 'ispell-process) ispell-process
			       (eq (ispell-process-status) 'run))
                  :help "Terminate Ispell subprocess"))
    (define-key map [ispell-pdict-save]
      `(menu-item "Save Dictionary"
                  ,(lambda () (interactive) (ispell-pdict-save t t))
                  :help "Save personal dictionary"))
    (define-key map [ispell-customize]
      `(menu-item "Customize..."
                  ,(lambda () (interactive) (customize-group 'ispell))
                  :help "Customize spell checking options"))
    (define-key map [ispell-help]
      ;; use (x-popup-menu last-nonmenu-event(list "" ispell-help-list)) ?
      `(menu-item "Help"
                  ,(lambda () (interactive) (describe-function 'ispell-help))
                  :help "Show standard Ispell keybindings and commands"))
    (define-key map [flyspell-mode]
      '(menu-item "Automatic spell checking (Flyspell)"
		  flyspell-mode
                  :help "Check spelling while you edit the text"
		  :button (:toggle . (bound-and-true-p flyspell-mode))))
    (define-key map [ispell-complete-word]
      '(menu-item "Complete Word" ispell-complete-word
                  :help "Complete word at cursor using dictionary"))
    (define-key map [ispell-complete-word-interior-frag]
      '(menu-item "Complete Word Fragment"
                  ispell-complete-word-interior-frag
                  :help "Complete word fragment at cursor"))

    (define-key map [ispell-continue]
      '(menu-item "Continue Spell-Checking" ispell-continue
		  :enable (and (boundp 'ispell-region-end)
			       (marker-position ispell-region-end)
			       (equal (marker-buffer ispell-region-end)
				      (current-buffer)))
                  :help "Continue spell checking last region"))
    (define-key map [ispell-word]
      '(menu-item "Spell-Check Word" ispell-word
                  :help "Spell-check word at cursor"))
    (define-key map [ispell-comments-and-strings]
      '(menu-item "Spell-Check Comments"
                  ispell-comments-and-strings
                  :help "Spell-check only comments and strings"))

    (define-key map [ispell-region]
      '(menu-item "Spell-Check Region" ispell-region
		  :enable mark-active
                  :help "Spell-check text in marked region"))
    (define-key map [ispell-message]
      '(menu-item "Spell-Check Message" ispell-message
		  :visible (eq major-mode 'mail-mode)
                  :help "Skip headers and included message text"))
    (define-key map [ispell-buffer]
      '(menu-item "Spell-Check Buffer" ispell-buffer
                  :help "Check spelling of selected buffer"))
    map)
  "Key map for ispell menu.")