Variable: mh-show-mode-abbrev-table

mh-show-mode-abbrev-table is a variable defined in mh-show.el.gz.

Value

#<obarray n=1>

Documentation

Abbrev table for mh-show-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/mh-e/mh-show.el.gz
;;;###mh-autoload
(define-derived-mode mh-show-mode text-mode "MH-Show"
  "Major mode for showing messages in MH-E.
\\<mh-show-mode-map>
Email addresses and URLs in the message are highlighted if the
option `goto-address-highlight-p' is on, which it is by default.
To view the web page for a highlighted URL or to send a message
using a highlighted email address, use the middle mouse button or
\\[goto-address-at-point]. See Info node `(mh-e)Sending Mail' to
see how to configure Emacs to send the message using MH-E.

The hook `mh-show-mode-hook' is called upon entry to this mode.

See also `mh-folder-mode'.

\\{mh-show-mode-map}"
  (if (boundp 'tool-bar-map)
      (setq-local tool-bar-map mh-show-tool-bar-map))
  (setq-local mail-header-separator mh-mail-header-separator)
  (setq paragraph-start (default-value 'paragraph-start))
  (setq buffer-invisibility-spec '((vanish . t) t))
  (setq-local line-move-ignore-invisible t)
  (make-local-variable 'font-lock-defaults)
  ;;(setq-local font-lock-support-mode nil)
  (cond
   ((equal mh-highlight-citation-style 'font-lock)
    (setq font-lock-defaults '(mh-show-font-lock-keywords-with-cite t)))
   ((equal mh-highlight-citation-style 'gnus)
    (setq font-lock-defaults '((mh-show-font-lock-keywords)
                               t nil nil nil
                               (font-lock-fontify-region-function
                                . mh-show-font-lock-fontify-region)))
    (mh-gnus-article-highlight-citation))
   (t
    (setq font-lock-defaults '(mh-show-font-lock-keywords t))))
  (when mh-decode-mime-flag
    (add-hook 'kill-buffer-hook #'mh-mime-cleanup nil t))
  (make-local-variable 'mh-show-folder-buffer)
  (buffer-disable-undo)
  (use-local-map mh-show-mode-map))