Variable: treemacs-header-toggles-button

treemacs-header-toggles-button is a variable defined in treemacs-header-line.el.

Value

#("(T)" 0 3
  (local-map
   (keymap
    (header-line keymap
		 (mouse-1
		  . #[257
		      "\304\305\306\307\310\203
�\311\202�\312\"\313\"\306\307\314	\203�\311\202�\312\"\301\"\306\307\315\n\203+�\311\202,�\312\"\302\"\306\307\316\203:�\311\202;�\312\"\303\"F\"\317\"\211\205Q�\320\321\322\306\"\"!\207"
		      [treemacs-show-hidden-files treemacs-follow-mode
						  treemacs-filewatch-mode
						  treemacs-fringe-indicator-mode
						  easy-menu-create-menu
						  nil vector format
						  "Dotfile Visibility (Currently %s)"
						  "Enabled" "Disabled"
						  treemacs-toggle-show-dotfiles
						  "Follow-Mode (Currently %s)"
						  "Filewatch-Mode (Currently %s)"
						  "Fringe-Indicator-Mode (Currently %s)"
						  x-popup-menu
						  call-interactively
						  lookup-key apply]
		      10
		      ("/root/.emacs.d/elpa/treemacs-20251226.1307/treemacs-header-line.elc"
		       . 135)
		      "e"])))
   face treemacs-header-button-face))

Documentation

Header button to open a minor-modes/toggles administration menu.

Source Code

;; Defined in ~/.emacs.d/elpa/treemacs-20251226.1307/treemacs-header-line.el
(cl-macrolet
    ((make-local-map
      (&rest body)
      `(-doto (make-sparse-keymap)
         (define-key [header-line mouse-1]
           (lambda (event)
             (interactive "e")
             ,@body)))))

  (defconst treemacs-header-close-button
    (propertize
     "(❌)"
     'local-map (make-local-map (delete-window (posn-window (event-start event))))
     'face 'treemacs-header-button-face)
    "Header button to close the treemacs window.")

  (defconst treemacs-header-projects-button
    (propertize
     "(P)"
     'local-map
     (make-local-map
      (let* ((menu
              (easy-menu-create-menu
               nil
               `(["Add Project"            treemacs-add-project]
                 ["Add Projectile Project" treemacs-projectile :visible (featurep 'treemacs-projectile)]
                 ["Remove Project"         treemacs-remove-project-from-workspace])))
             (choice (x-popup-menu event menu)))
        (when choice (call-interactively (lookup-key menu (apply 'vector choice))))))
     'face 'treemacs-header-button-face)
    "Header button to open a project administration menu.")

  (defconst treemacs-header-workspace-button
    (propertize
     "(W)"
     'local-map
     (make-local-map
      (let* ((menu
              (easy-menu-create-menu
               nil
               `(["Edit Workspaces"        treemacs-edit-workspaces]
                 ["Create Workspace"       treemacs-create-workspace]
                 ["Remove Workspace"       treemacs-remove-workspace]
                 ["Rename Workspace"       treemacs-rename-workspace]
                 ["Switch Workspace"       treemacs-switch-workspace]
                 ["Set Fallback Workspace" treemacs-set-fallback-workspace])))
             (choice (x-popup-menu event menu)))
        (when choice (call-interactively (lookup-key menu (apply 'vector choice))))) )
     'face 'treemacs-header-button-face)
    "Header button to open a workspace administration menu.")

  (defconst treemacs-header-toggles-button
    (propertize
     "(T)"
     'local-map
     (make-local-map
      (let* ((menu
              (easy-menu-create-menu
               nil
               `([,(format "Dotfile Visibility (Currently %s)"
                           (if treemacs-show-hidden-files "Enabled" "Disabled"))
                  treemacs-toggle-show-dotfiles]
                 [,(format "Follow-Mode (Currently %s)"
                           (if treemacs-follow-mode "Enabled" "Disabled"))
                  treemacs-follow-mode]
                 [,(format "Filewatch-Mode (Currently %s)"
                           (if treemacs-filewatch-mode "Enabled" "Disabled"))
                  treemacs-filewatch-mode]
                 [,(format "Fringe-Indicator-Mode (Currently %s)"
                           (if treemacs-fringe-indicator-mode "Enabled" "Disabled"))
                  treemacs-fringe-indicator-mode])))
             (choice (x-popup-menu event menu)))
        (when choice (call-interactively (lookup-key menu (apply 'vector choice))))) )
     'face 'treemacs-header-button-face)
    "Header button to open a minor-modes/toggles administration menu."))