Variable: vc-hg-log-view-mode-map

vc-hg-log-view-mode-map is a variable defined in vc-hg.el.gz.

Value

Documentation

Keymap for vc-hg-log-view-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/vc/vc-hg.el.gz
(define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
  (require 'add-log) ;; we need the add-log faces
  (let ((shortp (memq 'short vc-log-view-types)))
   (setq-local log-view-file-re regexp-unmatchable)
   (setq-local log-view-per-file-logs nil)
   (setq-local log-view-message-re
               (if shortp
                   (cadr vc-hg-root-log-format)
                 "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
   (setq-local tab-width 2)
   ;; Allow expanding short log entries.
   (when shortp
     (setq truncate-lines t)
     (setq-local log-view-expanded-log-entry-function
                 'vc-hg-expanded-log-entry))
   (setq-local log-view-font-lock-keywords
               (if shortp
                   (list (cons (nth 1 vc-hg-root-log-format)
                               (nth 2 vc-hg-root-log-format)))
                 (append
                  log-view-font-lock-keywords
                  '(
                    ;; Handle the case:
                    ;; user: FirstName LastName <foo@bar>
                    ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
                     (1 'change-log-name)
                     (2 'change-log-email))
                    ;; Handle the cases:
                    ;; user: foo@bar
                    ;; and
                    ;; user: foo
                    ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
                     (1 'change-log-email))
                    ("^date: \\(.+\\)" (1 'change-log-date))
                    ("^tag: +\\([^ ]+\\)$" (1 'highlight))
                    ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))))