Function: bug-reference--setup-from-vc-alist

bug-reference--setup-from-vc-alist is a byte-compiled function defined in bug-reference.el.gz.

Signature

(bug-reference--setup-from-vc-alist &optional REBUILD)

Documentation

Compute the bug-reference--setup-from-vc-alist(var)/bug-reference--setup-from-vc-alist(fun) value.

If REBUILD is non-nil, compute it again even if has been computed already. The value contains a few default entries, and entries generated from bug-reference-forge-alist.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/bug-reference.el.gz
(defun bug-reference--setup-from-vc-alist (&optional rebuild)
  "Compute the `bug-reference--setup-from-vc-alist' value.
If REBUILD is non-nil, compute it again even if has been computed
already.  The value contains a few default entries, and entries
generated from `bug-reference-forge-alist'."
  (if (and bug-reference--setup-from-vc-alist
           (null rebuild))
      bug-reference--setup-from-vc-alist
    (setq bug-reference--setup-from-vc-alist
          `(;; GNU projects on savannah.
            ;;
            ;; Not all of them use debbugs but that doesn't really
            ;; matter because the auto-setup is only performed if
            ;; `bug-reference-url-format' and
            ;; `bug-reference-bug-regexp' aren't set already.
            ("git\\.\\(?:sv\\|savannah\\)\\.gnu\\.org:"
             "\\(\\b\\(?:[Bb]ug ?#?\\)\\([0-9]+\\(?:#[0-9]+\\)?\\)\\)\\>"
             ,(lambda (_) "https://debbugs.gnu.org/%s"))

            ;; Entries for the software forges of
            ;; `bug-reference-forge-alist'.
            ,@(mapcar (lambda (entry)
                        (apply #'bug-reference--build-forge-setup-entry entry))
                      bug-reference-forge-alist)))))