Function: texinfo-update-node

texinfo-update-node is an autoloaded, interactive and byte-compiled function defined in texnfo-upd.el.gz.

Signature

(texinfo-update-node &optional BEGINNING END)

Documentation

Without any prefix argument, update the node in which point is located.

Interactively, a prefix argument means to operate on the region.

Warning: do NOT use this function if your Texinfo file uses @node lines without the Next, Previous, Up pointers, because the result could be an invalid Texinfo file due to known deficiencies in this command: it does not support @ignore and @if* directives.

The functions for creating or updating nodes and menus, and their keybindings, are:

    texinfo-update-node (&optional beginning end) M-x texinfo-update-node (texinfo-update-node)
    texinfo-every-node-update () M-x texinfo-every-node-update (texinfo-every-node-update)
    texinfo-sequential-node-update (&optional region-p)

    texinfo-make-menu (&optional region-p) M-x texinfo-make-menu (texinfo-make-menu)
    texinfo-all-menus-update () M-x texinfo-all-menus-update (texinfo-all-menus-update)
    texinfo-master-menu ()

    texinfo-indent-menu-description (column &optional region-p)

The texinfo-column-for-description variable specifies the column to which menu descriptions are indented. Its default value is 32.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/texnfo-upd.el.gz
;;; Updating a node

;;;###autoload
(defun texinfo-update-node (&optional beginning end)
  "Without any prefix argument, update the node in which point is located.
Interactively, a prefix argument means to operate on the region.

Warning: do NOT use this function if your Texinfo file uses @node
lines without the `Next', `Previous', `Up' pointers, because the
result could be an invalid Texinfo file due to known deficiencies
in this command: it does not support @ignore and @if* directives.

The functions for creating or updating nodes and menus, and their
keybindings, are:

    texinfo-update-node (&optional beginning end)    \\[texinfo-update-node]
    texinfo-every-node-update ()                \\[texinfo-every-node-update]
    texinfo-sequential-node-update (&optional region-p)

    texinfo-make-menu (&optional region-p)      \\[texinfo-make-menu]
    texinfo-all-menus-update ()                 \\[texinfo-all-menus-update]
    texinfo-master-menu ()

    texinfo-indent-menu-description (column &optional region-p)

The `texinfo-column-for-description' variable specifies the column to
which menu descriptions are indented. Its default value is 32."

  (interactive
   (if prefix-arg
       (list (point) (mark))))
  (if (null beginning)
      ;; Update a single node.
      (let ((auto-fill-function nil))
	(if (not (re-search-backward "^@node" (point-min) t))
	    (error "Node line not found before this position"))
	(texinfo-update-the-node)
	(message "Done...updated the node.  You may save the buffer."))
    ;; else
    (let ((auto-fill-function nil))
      (save-excursion
	(save-restriction
	  (narrow-to-region beginning end)
	  (goto-char (point-min))
	  (while (re-search-forward "^@node" (point-max) t)
	    (beginning-of-line)
	    (texinfo-update-the-node))
	  (goto-char (point-max))
	  (message "Done...nodes updated in region.  You may save the buffer."))))))