Function: diary-font-lock-keywords

diary-font-lock-keywords is an autoloaded and byte-compiled function defined in diary-lib.el.gz.

Signature

(diary-font-lock-keywords)

Documentation

Return a value for the variable diary-font-lock-keywords(var)/diary-font-lock-keywords(fun).

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/diary-lib.el.gz
;;;###cal-autoload
(defun diary-font-lock-keywords ()
  "Return a value for the variable `diary-font-lock-keywords'."
  (append
   (diary-font-lock-date-forms calendar-month-name-array
                               nil calendar-month-abbrev-array)
   (diary-font-lock-keywords-1 diary-hebrew-mark-entries
                               diary-hebrew-list-entries
                               cal-hebrew
                               calendar-hebrew-month-name-array-leap-year
                               diary-hebrew-entry-symbol)
   (diary-font-lock-keywords-1 diary-islamic-mark-entries
                               diary-islamic-list-entries
                               cal-islam
                               calendar-islamic-month-name-array
                               diary-islamic-entry-symbol)
   (diary-font-lock-keywords-1 diary-bahai-mark-entries
                               diary-bahai-list-entries
                               cal-bahai
                               calendar-bahai-month-name-array
                               diary-bahai-entry-symbol)
   (diary-font-lock-keywords-1 diary-chinese-mark-entries
                               diary-chinese-list-entries
                               cal-china
                               calendar-chinese-month-name-array
                               diary-chinese-entry-symbol)
   (list
    (cons
     (format "^%s.*$" (regexp-quote diary-include-string))
     'font-lock-keyword-face)
    (cons
     (format "^%s?\\(%s\\)" (regexp-quote diary-nonmarking-symbol)
             (regexp-quote diary-sexp-entry-symbol))
     '(1 font-lock-constant-face))
    (cons
     (format "^%s" (regexp-quote diary-nonmarking-symbol))
     'font-lock-constant-face)
    (cons
     (format "^%s?%s" (regexp-quote diary-nonmarking-symbol)
             (regexp-opt (mapcar #'regexp-quote
                                 (list diary-hebrew-entry-symbol
                                       diary-islamic-entry-symbol
                                       diary-bahai-entry-symbol
                                       diary-chinese-entry-symbol))
                         t))
     '(1 font-lock-constant-face))
    '(diary-font-lock-sexps . font-lock-keyword-face)
    ;; Don't need to worry about space around "-" because the first
    ;; match takes care of that.  It does mean the "-" itself may or
    ;; may not be fontified though.
    ;; diary-date-forms often include a final character that is not
    ;; part of the date (eg a non-digit to mark the end of the year).
    ;; This can use up the only space char between a date and time (b#7891).
    ;; Hence we use OVERRIDE, which can only override whitespace.
    ;; FIXME it's probably better to tighten up the diary-time-regexp
    ;; and drop the whitespace requirement below.
    `(,(format "\\(^\\|\\s-\\)%s\\(-%s\\)?" diary-time-regexp
               diary-time-regexp)
      . (0 'diary-time t)))))