Function: paragraph-indent-minor-mode

paragraph-indent-minor-mode is an interactive and byte-compiled function defined in text-mode.el.gz.

Signature

(paragraph-indent-minor-mode &optional ARG)

Documentation

Minor mode for editing text, with leading spaces starting a paragraph.

In this mode, you do not need blank lines between paragraphs when the first line of the following paragraph starts with whitespace, as with paragraph-indent-text-mode. Turning on Paragraph-Indent minor mode runs the normal hook paragraph-indent-text-mode-hook.

This is a minor mode. If called interactively, toggle the Paragraph-Indent minor mode mode. If the prefix argument is positive, enable the mode, and if it is zero or negative, disable the mode.

If called from Lisp, toggle the mode if ARG is toggle. Enable the mode if ARG is nil, omitted, or is a positive number. Disable the mode if ARG is a negative number.

To check whether the minor mode is enabled in the current buffer, evaluate paragraph-indent-minor-mode(var)/paragraph-indent-minor-mode(fun).

The mode's hook is called both when the mode is enabled and when it is disabled.

View in manual

Probably introduced at or before Emacs version 21.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/text-mode.el.gz
(define-minor-mode paragraph-indent-minor-mode
  "Minor mode for editing text, with leading spaces starting a paragraph.
In this mode, you do not need blank lines between paragraphs when the
first line of the following paragraph starts with whitespace, as with
`paragraph-indent-text-mode'.
Turning on Paragraph-Indent minor mode runs the normal hook
`paragraph-indent-text-mode-hook'."
  :initial-value nil
  ;; Change the definition of a paragraph start.
  (let ((ps-re "[ \t\n\f]\\|"))
    (if (string-prefix-p ps-re paragraph-start)
        (if (not paragraph-indent-minor-mode)
            (setq-local paragraph-start
                        (substring paragraph-start (length ps-re))))
      (if paragraph-indent-minor-mode
          (setq-local paragraph-start (concat ps-re paragraph-start)))))
  ;; Change the indentation function.
  (if paragraph-indent-minor-mode
      (add-function :override (local 'indent-line-function)
                    #'indent-to-left-margin)
    (remove-function (local 'indent-line-function)
                     #'indent-to-left-margin)))