Function: verilog-label-be

verilog-label-be is an interactive and byte-compiled function defined in verilog-mode.el.gz.

Signature

(verilog-label-be)

Documentation

Label matching begin ... end, fork ... join and case ... endcase statements.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/verilog-mode.el.gz
(defun verilog-label-be ()
  "Label matching begin ... end, fork ... join and case ... endcase statements."
  (interactive)
  (let ((cnt 0)
	(case-fold-search nil)
	(oldpos (point))
	(b (progn
	     (verilog-re-search-backward verilog-defun-re nil 'move)
	     (point-marker)))
	(e (progn
	     (verilog-re-search-forward verilog-end-defun-re nil 'move)
	     (point-marker))))
    (goto-char (marker-position b))
    (if (> (- e b) 200)
	(message "Relabeling module..."))
    (while (and
	    (> (marker-position e) (point))
	    (verilog-re-search-forward
	     verilog-auto-end-comment-lines-re
	     nil 'move))
      (goto-char (match-beginning 0))
      (let ((indent-str (verilog-indent-line)))
	(verilog-set-auto-endcomments indent-str 't)
	(end-of-line)
	(delete-horizontal-space))
      (setq cnt (1+ cnt))
      (if (= 9 (% cnt 10))
	  (message "%d..." cnt)))
    (goto-char oldpos)
    (if (or
	 (> (- e b) 200)
	 (> cnt 20))
	(message "%d lines auto commented" cnt))))