Variable: html-quick-keys

html-quick-keys is a customizable variable defined in sgml-mode.el.gz.

Value

nil

Documentation

Use C-c X combinations for quick insertion of frequent tags when non-nil.

This defaults to sgml-quick-keys, which see.

Probably introduced at or before Emacs version 19.31.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/sgml-mode.el.gz
(defcustom html-quick-keys sgml-quick-keys
  "Use C-c X combinations for quick insertion of frequent tags when non-nil.
This defaults to `sgml-quick-keys', which see."
  :set (lambda (sym val)
         (set-default sym val)
         (dolist (bind `((,(kbd "C-c p") . ,#'html-paragraph)
                         (,(kbd "C-c -") . ,#'html-horizontal-rule)
                         (,(kbd "C-c d") . ,#'html-div)
                         (,(kbd "C-c o") . ,#'html-ordered-list)
                         (,(kbd "C-c u") . ,#'html-unordered-list)
                         (,(kbd "C-c r") . ,#'html-radio-buttons)
                         (,(kbd "C-c c") . ,#'html-checkboxes)
                         (,(kbd "C-c l") . ,#'html-list-item)
                         (,(kbd "C-c h") . ,#'html-href-anchor)
                         (,(kbd "C-c f") . ,#'html-href-anchor-file)
                         (,(kbd "C-c n") . ,#'html-name-anchor)
                         (,(kbd "C-c #") . ,#'html-id-anchor)
                         (,(kbd "C-c i") . ,#'html-image)
                         (,(kbd "C-c s") . ,#'html-span)))
           (if val
               (define-key html-mode-map (car bind) (cdr bind))
             (define-key html-mode-map (car bind) nil t))))
  :set-after '(sgml-quick-keys)
  :type '(choice (const :tag "Enabled" t)
                 (const :tag "Enabled, and indent when closing tags" indent)
                 ;; Omit `close' because `electric-pair-mode' already
                 ;; takes care of paring "<" and ">".
                 (const :tag "Disabled" nil)))