Variable: read-passwd-mode

read-passwd-mode is a buffer-local variable defined in auth-source.el.gz.

Documentation

Non-nil if Read-Passwd mode is enabled.

Use the command read-passwd-mode(var)/read-passwd-mode(fun) to change this variable.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/auth-source.el.gz
(define-minor-mode read-passwd-mode
  "Toggle visibility of password in minibuffer."
  :group 'mode-line
  :group 'minibuffer
  :keymap read-passwd-map
  :version "30.1"

  (unless read-passwd-mode
    (setq read-passwd--mini-buffers
          (delq (current-buffer) read-passwd--mini-buffers)))
  (unless read-passwd--mini-buffers
    (let ((mode-string '(:eval read-passwd--mode-line-icon)))
      (if read-passwd-mode
          ;; Add `read-passwd--mode-line-icon'.
          (or (member mode-string global-mode-string)
              (setq global-mode-string
                    (append global-mode-string (list mode-string))))
        ;; Remove `read-passwd--mode-line-icon'.
        (setq global-mode-string
	      (delete mode-string global-mode-string)))))
  (when read-passwd-mode
    (push (current-buffer) read-passwd--mini-buffers))
  ;; Always hide the current password.
  (when read-passwd--mini-buffers
    (with-current-buffer (car read-passwd--mini-buffers)
      (read-passwd-toggle-visibility t))))