Function: consult-register

consult-register is an autoloaded, interactive and byte-compiled function defined in consult-register.el.

Signature

(consult-register &optional ARG)

Documentation

Load register and either jump to location or insert the stored text.

This command is useful to search the register contents. For quick access to registers it is still recommended to use the register functions consult-register-load and consult-register-store or the built-in built-in register access functions. The command supports narrowing, see consult-register--narrow. Marker positions are previewed. See jump-to-register and insert-register for the meaning of prefix ARG.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/consult-20260805.1130/consult-register.el
;;;###autoload
(defun consult-register (&optional arg)
  "Load register and either jump to location or insert the stored text.

This command is useful to search the register contents.  For quick access
to registers it is still recommended to use the register functions
`consult-register-load' and `consult-register-store' or the built-in
built-in register access functions.  The command supports narrowing, see
`consult-register--narrow'.  Marker positions are previewed.  See
`jump-to-register' and `insert-register' for the meaning of prefix ARG."
  (interactive "P")
  (consult-register-load
   (consult--read
    (consult-register--candidates)
    :prompt "Register: "
    :category 'multi-category
    :state
    (let ((preview (consult--jump-preview)))
      (lambda (action cand)
        ;; Preview only markers
        (funcall preview action
                 (when-let* ((reg (get-register cand)))
                   (and (markerp reg) reg)))))
    :group (consult--type-group consult-register--narrow)
    :narrow (consult--type-narrow consult-register--narrow)
    :sort nil
    :require-match t
    :history t ;; disable history
    :lookup #'consult--lookup-candidate)
   arg))