Function: edt-default-emulation-setup

edt-default-emulation-setup is a byte-compiled function defined in edt.el.gz.

Signature

(edt-default-emulation-setup &optional USER-SETUP)

Documentation

Setup emulation of DEC's EDT editor.

Optional argument USER-SETUP non-nil means called from function
edt-user-emulation-setup.

Source Code

;; Defined in /usr/src/emacs/lisp/emulation/edt.el.gz
(defun edt-default-emulation-setup (&optional user-setup)
  "Setup emulation of DEC's EDT editor.
Optional argument USER-SETUP non-nil means  called from function
`edt-user-emulation-setup'."
  ;; Setup default EDT global map by copying global map bindings.
  ;; This preserves ESC and C-x prefix bindings and other bindings we
  ;; wish to retain in EDT emulation mode keymaps.  It also permits
  ;; customization of these bindings in the EDT global maps without
  ;; disturbing the original bindings in global-map.
  (fset 'edt-default-ESC-prefix (copy-keymap 'ESC-prefix))
  (setq edt-default-global-map (copy-keymap (current-global-map)))
  (define-key edt-default-global-map "\e" 'edt-default-ESC-prefix)
  (define-prefix-command 'edt-default-gold-map)
  (edt-setup-default-bindings)
  ;; If terminal has additional function keys, the terminal-specific
  ;; initialization file can assign bindings to them via the optional
  ;; function edt-setup-extra-default-bindings.
  (if (fboundp 'edt-setup-extra-default-bindings)
      (edt-setup-extra-default-bindings))
  ;; Variable needed by edt-learn.
  (setq edt-learn-macro-count 0)
  ;; Display EDT text selection active within the mode line
  (or (assq 'edt-select-mode minor-mode-alist)
      (setq minor-mode-alist
	    (cons '(edt-select-mode edt-select-mode) minor-mode-alist)))
  ;; Display EDT direction of motion within the mode line
  (or (assq 'edt-direction-string minor-mode-alist)
      (setq minor-mode-alist
	    (cons
	     '(edt-direction-string edt-direction-string) minor-mode-alist)))
  (if user-setup
      (progn
        (setq edt-user-map-configured t)
        (fset 'edt-emulation-on (symbol-function 'edt-select-user-global-map)))
    (progn
      (fset 'edt-emulation-on (symbol-function 'edt-select-default-global-map))
      (edt-select-default-global-map)))
  ;; Keep the menu bar Buffers menu up-to-date in edt-default-global-map.
  (add-hook 'menu-bar-update-hook #'edt-default-menu-bar-update-buffers))