Function: gnus-agentize

gnus-agentize is an autoloaded, interactive and byte-compiled function defined in gnus-agent.el.gz.

Signature

(gnus-agentize)

Documentation

Allow Gnus to be an offline newsreader.

The gnus-agentize function is now called internally by gnus when gnus-agent is set. If you wish to avoid calling gnus-agentize, customize gnus-agent to nil.

This will modify the gnus-setup-news-hook, and message-send-mail-real-function variables, and install the Gnus agent minor mode in all Gnus buffers.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-agent.el.gz
;;;###autoload
(defun gnus-agentize ()
  "Allow Gnus to be an offline newsreader.

The `gnus-agentize' function is now called internally by gnus when
`gnus-agent' is set.  If you wish to avoid calling `gnus-agentize',
customize `gnus-agent' to nil.

This will modify the `gnus-setup-news-hook', and
`message-send-mail-real-function' variables, and install the Gnus agent
minor mode in all Gnus buffers."
  (interactive)
  (gnus-open-agent)
  (setq message-send-mail-real-function 'gnus-agent-send-mail)

  ;; If the servers file doesn't exist, auto-agentize some servers and
  ;; save the servers file so this auto-agentizing isn't invoked
  ;; again.
  (when (and (not (file-exists-p (nnheader-concat
				  gnus-agent-directory "lib/servers")))
	     gnus-agent-auto-agentize-methods)
    (gnus-message 3 "First time agent user, agentizing remote groups...")
    (mapc
     (lambda (server-or-method)
       (let ((method (gnus-server-to-method server-or-method)))
	 (when (memq (car method)
		     gnus-agent-auto-agentize-methods)
	   (push (gnus-method-to-server method)
		 gnus-agent-covered-methods)
	   (setq gnus-agent-method-p-cache nil))))
     (cons gnus-select-method gnus-secondary-select-methods))
    (gnus-agent-write-servers)))