Function: pr-ps-fast-fire

pr-ps-fast-fire is an autoloaded, interactive and byte-compiled function defined in printing.el.gz.

Signature

(pr-ps-fast-fire N-UP &optional SELECT)

Documentation

Fast fire function for PostScript printing.

If a region is active, the region will be printed instead of the whole buffer. Also if the current major-mode is defined in pr-mode-alist, the settings in pr-mode-alist will be used, that is, the current buffer or region will be printed using pr-ps-mode-ps-print.

Interactively, you have the following situations:

   <print> (pr-ps-fast-fire)
      The command prompts the user for a N-UP value and printing will
      immediately be done using the current active printer.

   C-u (universal-argument) <print> (pr-ps-fast-fire)
   C-u (universal-argument) 0 <print> (pr-ps-fast-fire)
      The command prompts the user for a N-UP value and also for a current
      PostScript printer, then printing will immediately be done using the new
      current active printer.

   C-u (universal-argument) 1 <print> (pr-ps-fast-fire)
      The command prompts the user for a N-UP value and also for a file name,
      and saves the PostScript image in that file instead of sending it to the
      printer.

   C-u (universal-argument) 2 <print> (pr-ps-fast-fire)
      The command prompts the user for a N-UP value, then for a current
      PostScript printer and, finally, for a file name. Then change the active
      printer to that chosen by user and saves the PostScript image in
      that file instead of sending it to the printer.

Noninteractively, the argument N-UP should be a positive integer greater than zero and the argument SELECT is treated as follows:

   If it's nil, send the image to the printer.

   If it's a list or an integer lesser or equal to zero, the command prompts
   the user for a current PostScript printer, then printing will immediately
   be done using the new current active printer.

   If it's an integer equal to 1, the command prompts the user for a file name
   and saves the PostScript image in that file instead of sending it to the
   printer.

   If it's an integer greater or equal to 2, the command prompts the user for a
   current PostScript printer and for a file name. Then change the active
   printer to that chosen by user and saves the PostScript image in that file
   instead of sending it to the printer.

   If it's a symbol which it's defined in pr-ps-printer-alist, it's the new
   active printer and printing will immediately be done using the new active
   printer.

   Otherwise, send the image to the printer.

Note that this command always behaves as if pr-auto-region and pr-auto-mode are both set to t.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/printing.el.gz
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Fast Commands


;;;###autoload
(defun pr-ps-fast-fire (n-up &optional select)
  "Fast fire function for PostScript printing.

If a region is active, the region will be printed instead of the whole buffer.
Also if the current major-mode is defined in `pr-mode-alist', the settings in
`pr-mode-alist' will be used, that is, the current buffer or region will be
printed using `pr-ps-mode-ps-print'.


Interactively, you have the following situations:

   \\[pr-ps-fast-fire]
      The command prompts the user for a N-UP value and printing will
      immediately be done using the current active printer.

   \\[universal-argument]   \\[pr-ps-fast-fire]
   \\[universal-argument] 0 \\[pr-ps-fast-fire]
      The command prompts the user for a N-UP value and also for a current
      PostScript printer, then printing will immediately be done using the new
      current active printer.

   \\[universal-argument] 1 \\[pr-ps-fast-fire]
      The command prompts the user for a N-UP value and also for a file name,
      and saves the PostScript image in that file instead of sending it to the
      printer.

   \\[universal-argument] 2 \\[pr-ps-fast-fire]
      The command prompts the user for a N-UP value, then for a current
      PostScript printer and, finally, for a file name.  Then change the active
      printer to that chosen by user and saves the PostScript image in
      that file instead of sending it to the printer.


Noninteractively, the argument N-UP should be a positive integer greater than
zero and the argument SELECT is treated as follows:

   If it's nil, send the image to the printer.

   If it's a list or an integer lesser or equal to zero, the command prompts
   the user for a current PostScript printer, then printing will immediately
   be done using the new current active printer.

   If it's an integer equal to 1, the command prompts the user for a file name
   and saves the PostScript image in that file instead of sending it to the
   printer.

   If it's an integer greater or equal to 2, the command prompts the user for a
   current PostScript printer and for a file name.  Then change the active
   printer to that chosen by user and saves the PostScript image in that file
   instead of sending it to the printer.

   If it's a symbol which it's defined in `pr-ps-printer-alist', it's the new
   active printer and printing will immediately be done using the new active
   printer.

   Otherwise, send the image to the printer.


Note that this command always behaves as if `pr-auto-region' and `pr-auto-mode'
are both set to t."
  (interactive (list (pr-interactive-n-up (pr-prompt-gs "PS print fast"))
		     current-prefix-arg))
  (let ((pr-auto-region t)
	(pr-auto-mode   t)
	filename)
    (cond ((null select))
	  ((listp select)
	   (pr-ps-name))
	  ((and (symbolp select)
		(assq select pr-ps-printer-alist))
	   (pr-menu-set-ps-title select))
	  ((integerp select)
	   (and (/= select 1)
		(pr-ps-name))
	   (and (>= select 1) (not pr-spool-p)
		(setq filename (pr-ps-outfile-preprint
				(if pr-print-using-ghostscript
				    "Fast GS "
				  "Fast "))))))
    (pr-ps-buffer-ps-print
     (if (integerp n-up)
	 (min (max n-up 1) 100)
       (error "n-up must be an integer greater than zero"))
     filename)))