Variable: help-at-pt-display-when-idle

help-at-pt-display-when-idle is a customizable variable defined in help-at-pt.el.gz.

Value

never

Documentation

Automatically show local help on point-over.

If the value is t, the string obtained from any kbd-help or help-echo property at point is automatically printed in the echo area, if nothing else is already displayed there, or after a quit. If both kbd-help and help-echo produce help strings, kbd-help is used. If the value is a list, the help only gets printed if there is a text or overlay property at point that is included in this list. Suggested properties are keymap, local-map, button and kbd-help. Any value other than t or a non-empty list disables the feature.

The text printed from the help-echo property is often only relevant when using the mouse. The presence of a kbd-help property guarantees that non mouse specific help is available.

This variable only takes effect after a call to help-at-pt-set-timer. The help gets printed after Emacs has been idle for help-at-pt-timer-delay seconds. You can call help-at-pt-cancel-timer to cancel the timer set by, and the effect of, help-at-pt-set-timer.

When this variable is set through Custom, help-at-pt-set-timer is called automatically, unless the value is never, in which case help-at-pt-cancel-timer is called. Specifying an empty list of properties through Custom will set the timer, thus enabling buffer local values. It sets the actual value to nil. Thus, Custom distinguishes between a nil value and other values that disable the feature, which Custom identifies with never. The default is never.

Eldoc uses the echo area to display documentation. As such it conflicts with help-at-pt-display-when-idle due to the use of the echo area. If you use Eldoc, consider setting eldoc-help-at-pt instead.

View in manual

Probably introduced at or before Emacs version 22.1.

Source Code

;; Defined in /usr/src/emacs/lisp/help-at-pt.el.gz
;;;###autoload
(defcustom help-at-pt-display-when-idle 'never
  "Automatically show local help on point-over.
If the value is t, the string obtained from any `kbd-help' or
`help-echo' property at point is automatically printed in the
echo area, if nothing else is already displayed there, or after a
quit.  If both `kbd-help' and `help-echo' produce help strings,
`kbd-help' is used.  If the value is a list, the help only gets
printed if there is a text or overlay property at point that is
included in this list.  Suggested properties are `keymap',
`local-map', `button' and `kbd-help'.  Any value other than t or
a non-empty list disables the feature.

The text printed from the `help-echo' property is often only
relevant when using the mouse.  The presence of a `kbd-help'
property guarantees that non mouse specific help is available.

This variable only takes effect after a call to
`help-at-pt-set-timer'.  The help gets printed after Emacs has
been idle for `help-at-pt-timer-delay' seconds.  You can call
`help-at-pt-cancel-timer' to cancel the timer set by, and the
effect of, `help-at-pt-set-timer'.

When this variable is set through Custom, `help-at-pt-set-timer'
is called automatically, unless the value is `never', in which
case `help-at-pt-cancel-timer' is called.  Specifying an empty
list of properties through Custom will set the timer, thus
enabling buffer local values.  It sets the actual value to nil.
Thus, Custom distinguishes between a nil value and other values
that disable the feature, which Custom identifies with `never'.
The default is `never'.

Eldoc uses the echo area to display documentation.  As such it
conflicts with `help-at-pt-display-when-idle' due to the use of
the echo area.  If you use Eldoc, consider setting
`eldoc-help-at-pt' instead."
  :group 'help-at-pt
  :type '(choice  (const :tag "Always"
			 :format "%t\n%h"
			 :doc
			 "This choice can get noisy.
The text printed from the `help-echo' property is often only
relevant when using the mouse.  If you mind about too many
messages getting printed in the echo area, use \"In certain
situations\".  See the documentation there for more information."
			 t)
		  (repeat :tag "In certain situations"
			  ;; unless we specify 0 offset the doc string
			  ;; for this choice gets indented very
			  ;; differently than for the other two
			  ;; choices, when "More" is selected.
			  :offset 0
			  :format "%{%t%}:\n%v%i\n%h"
			  :doc
			  "This choice lets you specify a list of \
text properties.
Presence of any of these properties will trigger display of
available local help on point-over.
If you use this alternative through Custom without listing any
properties, a timer will be set anyway.  This will enable buffer
local values.  Use \"Never\" if you do not want a timer to be set.

Suggested properties:
The `keymap' and `local-map' properties change keybindings in
parts of the buffer.  Some of these keymaps are mode independent
and are not mentioned in the mode documentation.  Hence, the help
text is likely to be useful.
Specifying `button' is relevant in Custom and similar buffers.
In these buffers, most, but not all, of the text shown this way is
available by default when using tab, but not on regular point-over.
The presence of a `kbd-help' property guarantees that non mouse
specific help is available."
			  :value (keymap local-map button kbd-help)
			  symbol)
		  (other :tag "Never"
			 :format "%t\n%h"
			 :doc
			 "This choice normally disables buffer local values.
If you choose this value through Custom and a timer checking for
local help is currently active, it will be canceled.  No new
timer will be set.  Call `help-at-pt-set-timer' after choosing
this option, or use \"In certain situations\" and specify no text
properties, to enable buffer local values."
			 never))
  :initialize 'custom-initialize-default
  :set (lambda (variable value)
         (set-default variable value)
         (if (eq value 'never)
             (help-at-pt-cancel-timer)
           (help-at-pt-set-timer)))
  :set-after '(help-at-pt-timer-delay)
  :require 'help-at-pt)