Variable: idlwave-shell-electric-debug-mode

idlwave-shell-electric-debug-mode is a buffer-local variable defined in idlw-shell.el.gz.

Documentation

Non-nil if Idlwave-Shell-Electric-Debug mode is enabled.

Use the command idlwave-shell-electric-debug-mode(var)/idlwave-shell-electric-debug-mode(fun) to change this variable.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/obsolete/idlw-shell.el.gz
(define-minor-mode idlwave-shell-electric-debug-mode
  "Toggle Idlwave Shell Electric Debug mode.

When Idlwave Shell Electric Debug mode is enabled, the Idlwave
Shell debugging commands are available as single key sequences."
  :lighter " *Debugging*"
  (cond
   (idlwave-shell-electric-debug-mode
    (set (make-local-variable 'idlwave-shell-electric-debug-read-only)
	 buffer-read-only)
    (setq buffer-read-only t)
    (add-to-list 'idlwave-shell-electric-debug-buffers (current-buffer))
    (if idlwave-shell-stop-line-overlay
        (overlay-put idlwave-shell-stop-line-overlay 'face
		     idlwave-shell-electric-stop-line-face))
    (if (facep 'fringe)
        (set-face-foreground 'fringe idlwave-shell-electric-stop-color
			     (selected-frame)))
    (message
     "Electric Debugging mode entered.  Press [C-?] for help, [q] to quit"))
   (t
    ;; Return to previous read-only state
    (setq buffer-read-only (if (boundp 'idlwave-shell-electric-debug-read-only)
			       idlwave-shell-electric-debug-read-only))
    (setq idlwave-shell-electric-debug-buffers
	  (delq (current-buffer) idlwave-shell-electric-debug-buffers))
    (if idlwave-shell-stop-line-overlay
        (overlay-put idlwave-shell-stop-line-overlay 'face
		     idlwave-shell-stop-line-face)
      (if (facep 'fringe)
	  (set-face-foreground 'fringe (face-foreground 'default)))))))