Variable: reftex-isearch-minor-mode

reftex-isearch-minor-mode is a customizable variable defined in reftex-global.el.gz.

Value

nil

Documentation

Non-nil if Reftex-Isearch minor mode is enabled.

See the reftex-isearch-minor-mode(var)/reftex-isearch-minor-mode(fun) command for a description of this minor mode. Setting this variable directly does not take effect; either customize it (see the info node (emacs)Easy Customization) or call the function reftex-isearch-minor-mode(var)/reftex-isearch-minor-mode(fun).

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/reftex-global.el.gz
;; NB this is a global autoload - see reftex.el.
;;;###autoload
(define-minor-mode reftex-isearch-minor-mode
  "When on, isearch searches the whole document, not only the current file.
This minor mode allows isearch to search through all the files of
the current TeX document."
  :lighter "/I"
  :global t
  :group 'reftex
  (if reftex-isearch-minor-mode
      (progn
	(dolist (crt-buf (buffer-list))
	  (with-current-buffer crt-buf
	    (when reftex-mode
	      (if (boundp 'multi-isearch-next-buffer-function)
                  (setq-local multi-isearch-next-buffer-function
                              #'reftex-isearch-switch-to-next-file)
                (setq-local isearch-wrap-function
                            #'reftex-isearch-wrap-function)
                (setq-local isearch-search-fun-function
                            (lambda () #'reftex-isearch-isearch-search))
                (setq-local isearch-push-state-function
                            #'reftex-isearch-push-state-function)
                (setq-local isearch-next-buffer-function
                            #'reftex-isearch-switch-to-next-file)))))
	(add-hook 'reftex-mode-hook #'reftex-isearch-minor-mode))
    (dolist (crt-buf (buffer-list))
      (with-current-buffer crt-buf
	(when reftex-mode
	  (if (boundp 'multi-isearch-next-buffer-function)
	      (kill-local-variable 'multi-isearch-next-buffer-function)
	    (kill-local-variable 'isearch-wrap-function)
	    (kill-local-variable 'isearch-search-fun-function)
	    (kill-local-variable 'isearch-push-state-function)
	    (kill-local-variable 'isearch-next-buffer-function)))))
    (remove-hook 'reftex-mode-hook #'reftex-isearch-minor-mode)))